Creating Instructions
The next step is to define the different kinds of trials that will be used in the experiment. The types of trials you define will correspond to the different conditions of the experiment. This experiment has four conditions, one condition for each of the four possible combinations of prime and target categories.
First, let's define trials involving pleasant primes and pleasant targets by creating the following trial element.
<trial pp>
/ pretrialpause = 300
/ validresponse = ("a", "5")
/ correctresponse = ("5")
/ stimulusframes = [1=forwardmask; 10=pleasantprime; 13=backwardmask; 14=pleasanttarget]
/ posttrialpause = 100
</trial>
The trial element is called "pp", which is short for "pleasant pleasant" because the trial presents both a pleasant prime and pleasant target.
The posttrialpause attribute tells Inquisit to pause 300 milliseconds before each trial is executed.
The validresponse attribute specifies which keys a subject can press to register their response. Remember we already talked about these responses when the instructions were created. When the participant responds by pressing the "a" or the "5" key, Inquisit will advance to the next trial.
The correctresponse attribute tells Inquisit which responses are considered correct. In this trial, "5" is correct.
the stimulusframes attribute is slightly more technical because it is closely connected to how digital monitors operate. Computer monitors repaint the screen from top to bottom according to a fixed interval called a "frame" (a.k.a., vertical retrace interval). Most standard monitors repaint the screen about every 10 to 17 milliseconds. To determine the frequency at which your monitor repaints the screen, select the "Check Hardware" command from Inquisit's Tools menu. Inquisit will run at any frequency. If you decide you would like to change the retrace frequency of your video system, you should check the manufacturer's documentation for the specifics on your monitor. Typically, the frame rate can be controlled from Display settings within Windows.
Thus, the stimulus presentation sequence is defined in terms of discrete frames rather than times. The entire presentation sequence consists of as many frames as are specified in the frames attribute (14 in this case). So, a forwardmask is presented at the onset of the first frame of the trial. This forwardmask remains on the screen until it is overwritten by a prime stimulus on the 10th frame. The prime stimulus remains on the screen for 3 frames (50 ms on a 60 hz monitor), before it is overwritten by a backward mask on the 13th frame. Finally, a target is presented on the 14th frame and remains on the screen until the subject responds.
So you see, you have to do a little calculating here to decide the time each frame is to be presented. 3 frames on a 60 hz monitor is the equivalent of 50 ms because:
3 (frames) x 16.7 (ms) = 50.1 (ms).
Finall, the posttrialpause atribute tells Inquisit to wait 100 ms after this trial before advancing to the next trial.
Remember, this was just one type of trial. We need to define 3 more trial types. The rest of the trials will be very similar to the first. Many experiments change only minor details from trial to trial; a word list, an order of presentation, response variables, etc. Once you have the first trial coded, you are ready to make the rest. It's very easy to do that in Inquisit. You can copy and paste your code for trial one and then just change the minor variables. Let's see what the other trial codes look like.
<trial pu>
/ pretrialpause = 300
/ validresponse = ("a", "5")
/ correctresponse = ("a")
/ stimulusframes = [1=forwardmask; 10=pleasantprime; 13=backwardmask; 14=unpleasanttarget]
/ posttrialpause = 100
</trial>
<trial up>
/ pretrialpause = 300
/ validresponse = ("a", "5")
/ correctresponse = ("5")
/ stimulusframes = [1=forwardmask; 10=unpleasantprime; 13=backwardmask; 14=pleasanttarget]
/ posttrialpause = 100
</trial>
<trial uu>
/ pretrialpause = 300
/ validresponse = ("a", "5")
/ correctresponse = ("a")
/ stimulusframes = [1=forwardmask; 10=unpleasantprime; 13=backwardmask; 14=unpleasanttarget]
/ posttrialpause = 100
</trial>
The three trials above differ from the original only by which stimuli they present and which response is considered correct. Together, the four trials capture the four combinations of pleasant and unpleasant prime and target stimuli.
| Creating Instructions |
Creating Blocks |