Creating Trials

The next step is to define the different kinds of trials that will be used in the Dot Probe Task. Trial elements control which stimuli are presented and how the subject may respond to those stimuli. There are eight types of trials used in this task depending on which category of word is presented in the upper position, and whether the word is replaced by a "!" or another word.

First, let's define trials that do not replace the words with a '!'.

<trial pleasant>  
/ stimulustimes = [1=focuspoint; 500=pleasanttop, unpleasantbottom]
/ inputdevice = voicekey
</trial>

The trial element's name is pleasant . On each line of data in the data file corresponding to this type of trial, this trial name is written.

The stimulustimes attribute defines the stimulus presentation sequence of the trial. The focus stimulus is presented for 500 milliseconds, after which pleasant and unpleasant words are presented in the upper and lower positions respectively.

The inputdevice attribute specifies the type of input expected from the participant. In this case, the inputdevice is "voicekey", which means that Inquisit will treat any sound through the microphone as a valid response, regardless of whether the sound was a valid word. If we cared about whether the spoken response was an actual word, we could have set this parameter to "speech", in which case Inquisit will use a speech recognition engine to analyze the content of what was said.

Next, we'll define a trial elementsimilar to pleasant, differing only in the location where the pleasant and unpleasant stimulis are presented. Here's the definition of trials with unpleasant words in the top position:

<trial unpleasant>  
/ stimulustimes = [1=focuspoint; 500=unpleasanttop, pleasantbottom]
/ inputdevice = voicekey
</trial>

Next come the trials in which one of the words is replaced by a '!'.

<trial pleasanttargettop>  
/ stimulustimes = [1=focuspoint; 500=pleasanttop, unpleasantbottom]
/ inputdevice = voicekey
/ responsetrial = (anyresponse, targettoppleasant)
</trial>

This trial is similar to the two trials above, except that it includes the responsetrial command. The response trial specifies a follow up trial to run if a particular response is given. In this case, the followup trial is named "targettopleasant" and the response is any response. So, whenever this trial runs, it is immediately followed by a trial named "targettoppleasant" to be defined below. This follow up trial presents the '!' stimulus and times the spacebar press.

We will now define the other 2 such trials based on whether the pleasant word is in the upper or lower position, and whether the target is in the upper or lower position.

Trials with insect names classified with the "a" key:

<trial unpleasanttargettop>  
/ stimulustimes = [1=focuspoint; 500=unpleasanttop, pleasantbottom]
/ inputdevice = voicekey
/ responsetrial = (anyresponse, targettopunpleasant)
</trial>

<trial pleasanttargetbottom>  
/ stimulustimes = [1=focuspoint; 500=pleasanttop, unpleasantbottom]
/ inputdevice = voicekey
/ responsetrial = (anyresponse, targetbottompleasant)
</trial>

<trial unpleasanttargetbottom>  
/ stimulustimes = [1=focuspoint; 500=unpleasanttop, pleasantbottom]
/ inputdevice = voicekey
/ responsetrial = (anyresponse, targetbottomunpleasant)
</trial>

Finally, we'll define the actual follow up trials that present the '!' in the upper or lower position. The first two such trials are identical except for the name. Note that they specify "keyboard" as the inputdevice (this is actually the default, so this command is optional), and spacebar is listed as the only valid and correct response.

<trial targettoppleasant>
/ stimulustimes = [1=targettop]
/ inputdevice = keyboard
/ correctresponse = (" ")
</trial>

<trial targettopunpleasant> 
/ stimulustimes = [1=targettop]
/ inputdevice = keyboard
/ correctresponse = (" ")
</trial>

Since these two trials are identical, why did we define two such trials instead of one? The reason is so that we can easily determine in the data file whether the follow up trial was preceded by an unpleasant or pleasant word. Specifically, the "targettoppleasant" trial is always run after a pleasant word was presented in the upper position, and the "targettopunpleasant" is run after an unpleasant word was in the upper position. Thus, we can analyze the effect of pleasant vs unpleasant by looking at the trial name rather than what was presented on the previous trial.

Last, we'll define the two trials that present the target '!' in the lower position.

<trial targetbottompleasant>  
/ stimulustimes = [1=targetbottom]
/ inputdevice = keyboard
/ correctresponse = (" ")
</trial>

<trial targetbottomunpleasant>
/ stimulustimes = [1=targetbottom]
/ inputdevice = keyboard
/ correctresponse = (" ")
</trial>

Again, these two trials are identical except for their name, but we can use the name to identify whether the preceding trial presented a pleasant or unpleasant word in the upper position.

Creating Instructions

Creating Blocks